FPGA SDR(7)AM復調


2018/07/07 追記:Cyclone IV EP4CE6E22のAM/FMラジオでは、ALTERA_CORDICのVector Translateを使ってFM用のPM復調とAM復調をまとめて計算するようにしました。Cyclone II EP2C5T144のAM/FMラジオでは二乗和は式で、Sqrt()だけALTSQRTを使っています。

 

FIRフィルタから出力されるIQ信号の振幅

    $$\sqrt{I^2 + Q^2}$$

を計算して音声信号に復調できます。

    $$I^2 + Q^2$$

の部分は同期検波で使ったALTMULT_ADDを2入力にして使います。

SQRTはALTSQRTを使います。MegaWizardが頻繁にエラーダイアログを表示しますが、閉じ続ければ問題なく生成されます。

 

`define CYCLE_1SEC 50000000


module SPIbridge
(
	input wire RST_N,
	input wire CLK,
	
	input wire SPI_NSS,
	input wire SPI_SCLK,
	output wire SPI_MISO,
	input wire SPI_MOSI,
	
	output wire [3:0] LED,
	
	input wire [7:0] ADC,
	output wire ENCODE,
	
	output reg [9:0] DAC,
	output wire DACCLK	
);


	wire [31:0] pio0;
	wire [31:0] pio1;

	reg [9:0] uadc_r;
	wire [9:0] adc;

	wire [9:0] sin;
	wire [9:0] cos;
	
	wire [19:0] i;
	wire [19:0] q;

	wire [18:0] icic;
	wire icic_valid;
	wire [18:0] qcic;
	wire qcic_valid;

	wire [9:0] ifir;
	wire ifir_valid;
	wire [9:0] qfir;
	wire qfir_valid;

	wire [20:0] i2q2;
	wire [9:0] iq;

	wire [9:0] dac;

	
	QsysCore QsysCore_inst (
		  .clk_clk                                                                                         (CLK),
		  .reset_reset_n                                                                                   (RST_N),
		  .spi_slave_to_avalon_mm_master_bridge_0_export_0_mosi_to_the_spislave_inst_for_spichain          (SPI_MOSI),
		  .spi_slave_to_avalon_mm_master_bridge_0_export_0_nss_to_the_spislave_inst_for_spichain           (SPI_NSS),
		  .spi_slave_to_avalon_mm_master_bridge_0_export_0_miso_to_and_from_the_spislave_inst_for_spichain (SPI_MISO),
		  .spi_slave_to_avalon_mm_master_bridge_0_export_0_sclk_to_the_spislave_inst_for_spichain          (SPI_SCLK),
		  .pio_0_external_connection_export                                                                (pio0),
		  .pio_1_external_connection_export                                                                (pio1)
	);


	assign LED = ~pio0[3:0];

	always @(posedge CLK) begin
		uadc_r <= { ADC, 2'b00 };
	end
	assign ENCODE = CLK;
	assign adc = (uadc_r[9] == 0) ? uadc_r + 10'h200 : uadc_r - 10'h200;

	nco nco_inst (
		.clk       (CLK),
		.reset_n   (RST_N),
		.clken     (1'b1),
		.phi_inc_i (pio1),
		.fsin_o    (sin),
		.fcos_o    (cos),
		.out_valid ()
		);

	altmul altmul_inst_i (
		.clock0 (CLK),
		.dataa_0 (adc),
		.datab_0 (cos),
		.result (i)
		);

	altmul altmul_inst_q (
		.clock0 (CLK),
		.dataa_0 (adc),
		.datab_0 (sin),
		.result (q)
		);

	cic cic_inst_i (
		.clk       (CLK),
		.reset_n   (RST_N),
		.in_error  (2'b00),
		.in_valid  (1'b1),
		.in_ready  (),
		.in_data   (i),
		.out_data  (icic),
		.out_error (),
		.out_valid (icic_valid),
		.out_ready (1'b1)
	);

	cic cic_inst_q (
		.clk       (CLK),
		.reset_n   (RST_N),
		.in_error  (2'b00),
		.in_valid  (1'b1),
		.in_ready  (),
		.in_data   (q),
		.out_data  (qcic),
		.out_error (),
		.out_valid (qcic_valid),
		.out_ready (1'b1)
	);
 
	fir fir_inst_i (
		.clk       (CLK),
		.reset_n   (RST_N),
		.ast_sink_data (icic),
		.ast_sink_valid (icic_valid),
		.ast_sink_error (2'b00),
		.ast_source_data (ifir),
		.ast_source_valid (ifir_valid),
		.ast_source_error ()
	);
 
	fir fir_inst_q (
		.clk       (CLK),
		.reset_n   (RST_N),
		.ast_sink_data (qcic),
		.ast_sink_valid (qcic_valid),
		.ast_sink_error (2'b00),
		.ast_source_data (qfir),
		.ast_source_valid (qfir_valid),
		.ast_source_error ()
	);

	altmultadd altmultadd_inst (
		.clock0 (CLK),
		.dataa_0 (ifir),
		.dataa_1 (qfir),
		.datab_0 (ifir),
		.datab_1 (qfir),
		.ena0 (ifir_valid),
		.result (i2q2)
	);
	
	sqrt	sqrt_inst (
		.radical ( i2q2[20:1] ),
		.q ( iq ),
		.remainder ()
	);

	assign dac = iq;
	always @(posedge CLK) begin
		if (ifir_valid) begin
			DAC <= (dac[9] == 0) ? dac + 10'h200 : dac - 10'h200;
		end
	end
	assign DACCLK = CLK;


endmodule

使用するリソースはこんな感じです。

Androidアプリ「GUI Maker for Avalon Bus – FPGA SPI Bridge Panel」に”NCO”パネルを追加して、NCOの周波数を放送周波数に合わせるとDACから音声信号が出力されます。まだアンプを繋いでいないのでクリスタルイヤホンのシャリシャリした音ですが明瞭に聞こえます。

 

DAC出力にオペアンプをボルテージフォロアで繋いでアンプ内蔵スピーカにでも繋いでみましょう。ADCのアンチエイリアシングフィルタをどうするかも後回しにしていました。